Pentagram of Venus

The planet Venus orbits the sun at roughly 13 times every 8 earth years. Specifically, The Earth orbits the Sun once every 365.256 days, and Venus orbits the Sun once every 224.701 days. So, Venus orbits the Sun in 224.701 / 365.256 ≈ 0.615187 Earth years. By coincidence, 8/13 ≈ 0.615385 . Pretty close! A thorough article on the Pentagram by the Grand Lodge of British Columbia and Yukon reports:
De Vogel, Goff and Van Buren tell us that the use of the pentagram dates back to Uruk IV (c.3500BCE) in ancient Mesopotamia where the general sense seems to be “heavenly body.” By the cuneiform period (post 2600 BCE) the pentagram or symbol UB means “region,” “heavenly quarter” or “direction”. “That this symbol always has a specific unambiquous meaning continues to be an unsupported hypothesis.” It is found on potsherds in the location of Uruk (near the mouth of the Gulf), and more frequently on Jemdet Nasr (3100-2900 BCE) and Proto-Elamite tablets (3000-2500 BCE). Examples elsewhere are infrequent. Historically, it does not appear to be equated with Venus. Venus is equated with the Sumarian goddess, Ishtar (Ishhara, Irnini, Inanna) whose symbol is an eight or sixteen point star. Amongst the Hebrews, the five point symbol was ascribed to Truth and to the five books of the Pentateuch. In Ancient Greece, it was called the Pentalpha. Pythagorians considered it an emblem of perfection or the symbol of the human being. The pentagram was also associated with the golden ratio (which it includes), and the dodecahedron, the fifth Platonic solid, which has twelve pentagonal faces and was considered by Plato to be a symbol of the heavens. Burkert says that the pentagram had a secret significance and power to the pythagoreans, and was used as a password or symbol of recognition amongst themselves.
The follow Processing sketch simulates the earth and Venus, along with the pattern created by their two orbits: [raw] [/raw] Code for the simulation follows。 You can edit and run this code on the KTBYTE Coder
PGraphics pattern; //stores the lines in the drawing
float earthRadius, venusRadius; //stores the distance of Earth and Venus from center
float earthAngle, venusAngle;   //stores the angle around the sun

//Earth moves 8 times for every 13 by Venus:
float earthAngleSpeed = 2 * PI / 60 / 20 * 8, venusAngleSpeed = 2 * PI / 60 / 20 * 13;
void setup() {
  size(500, 500);
  pattern = createGraphics(width, height);
  earthRadius = width / 2.0 * 2 / 3; //Put earth further from sun than venus
  venusRadius = width / 2.0 / 2;
  pattern.smooth();
}

void draw() {
  background(0);
  image(pattern, 0, 0);
  float centerX = width / 2, centerY = height/2;
  //ellipse(centerX, centerY, 10,10); //Draw optional sun
  float earthX = centerX + earthRadius * cos(earthAngle);
  float earthY = centerY + earthRadius * sin(earthAngle);
  noStroke();
  fill(0, 0, 100);
  ellipse(earthX, earthY, 10, 10); //Draw earth

  float venusX = centerX + venusRadius * cos(venusAngle);
  float venusY = centerY + venusRadius * sin(venusAngle);
  fill(100, 100, 0);
  ellipse(venusX, venusY, 10, 10); //draw Venus

  pattern.beginDraw();
  if (venusAngle > 2 * PI * 13) {
    pattern.background(0); //reset drawing every 8 years of earth
    earthAngle = venusAngle = 0;
  }
  pattern.stroke(255, 100); //add persistent lines between earth/venus
  pattern.line(earthX, earthY, venusX, venusY);
  pattern.endDraw();

  earthAngle += earthAngleSpeed; //increment angles by speed
  venusAngle += venusAngleSpeed;
}

One Reply to “Pentagram of Venus”

Leave a Reply

Your email address will not be published. Required fields are marked *